I have a user who has only one arm. How can she select multiple sheets in
Excel? I know that she can right-click a sheet tab and choose "Select all
sheets". But how can she select non-adjacent sheets? She can't use Ctrl +
Click to select the sheets, as that would require the use of two hands. Does
anyone know a command that would help her?

Thanks very much in advance,

Steve Vincent

Take a look at the Windows Accessibility settings (in the Control Panel)
There's an option for StickyKeys. When that is engaged, if the user presses
the [Ctrl] key one time, it remains pressed...allowing multiple selections.
Experiment with the settings.

Does that help?

***********
Regards,
Ron

XL2002, WinXP-Pro


"Steve Vincent" wrote:

I have a user who has only one arm. How can she select multiple sheets in
Excel? I know that she can right-click a sheet tab and choose "Select all
sheets". But how can she select non-adjacent sheets? She can't use Ctrl +
Click to select the sheets, as that would require the use of two hands. Does
anyone know a command that would help her?

Thanks very much in advance,

Steve Vincent

Maybe not a good solution but in windows control panel under accessibility
there is something called sticky keys where you can press ctrl and it sticks
without holding down, then select the non adjacent sheets. You can configure
the sticky keys to different options on how to turn them on/off beeping
warning etc.


--

Regards,

Peo Sjoblom

http://nwexcelsolutions.com


"Steve Vincent" wrote in message
...
I have a user who has only one arm. How can she select multiple sheets in
Excel? I know that she can right-click a sheet tab and choose "Select all
sheets". But how can she select non-adjacent sheets? She can't use Ctrl
+
Click to select the sheets, as that would require the use of two hands.
Does
anyone know a command that would help her?

Thanks very much in advance,

Steve Vincent

How about a macro that allows her to select the sheets to be selected by name?

If you want to try, create a new workbook.
Hit alt-F11 to get to the VBE.
Insert a userform (call it frmSelectSheets) with two buttons (cancel and ok) and
one listbox (for the names).

The put this code behind the userform:


Option Explicit
Private Sub CommandButton1_Click()
Unload Me
End Sub
Private Sub CommandButton2_Click()
Dim iCtr As Long
Dim myReplace As Boolean

myReplace = True
With Me.ListBox1
For iCtr = 1 To Me.ListBox1.ListCount
If .Selected(iCtr - 1) Then
ActiveWorkbook.Sheets(iCtr).Select Replace:=myReplace
myReplace = False
End If
Next iCtr
End With

Unload Me
End Sub
Private Sub UserForm_Initialize()
Dim iCtr As Long

With Me.ListBox1
.MultiSelect = fmMultiSelectMulti
.ListStyle = fmListStyleOption
End With

For iCtr = 1 To ActiveWorkbook.Sheets.Count
If Sheets(iCtr).Visible = xlSheetVisible Then
Me.ListBox1.AddItem Sheets(iCtr).Name
End If
Next iCtr

With Me.CommandButton1
.Caption = "Cancel"
.Cancel = True
End With

With Me.CommandButton2
.Caption = "Ok"
.Default = True
End With

Me.Caption = "Select Sheets"

End Sub

Then put this code in a General module. It creates a toolbar that contains one
button--to show that userform.


Option Explicit
Public Const ToolBarName As String = "SelectSheets"
Sub Auto_Open()
Call CreateMenubar
End Sub
Sub Auto_Close()
Call RemoveMenubar
End Sub
Sub RemoveMenubar()
On Error Resume Next
Application.CommandBars(ToolBarName).Delete
On Error GoTo 0
End Sub
Sub CreateMenubar()

Dim iCtr As Long

Dim MacNames As Variant
Dim CapNamess As Variant
Dim TipText As Variant

Call RemoveMenubar

MacNames = Array("ShowSelectSheetsForm")

CapNamess = Array("Select Sheets")

TipText = Array("Click here to select lots of sheets")

With Application.CommandBars.Add
.Name = ToolBarName
.Left = 200
.Top = 200
.Protection = msoBarNoProtection
.Visible = True
.Position = msoBarFloating

For iCtr = LBound(MacNames) To UBound(MacNames)
With .Controls.Add(Type:=msoControlButton)
.OnAction = "'" & ThisWorkbook.Name & "'!" & MacNames(iCtr)
.Caption = CapNamess(iCtr)
.Style = msoButtonIconAndCaption
.FaceId = 71 + iCtr
.TooltipText = TipText(iCtr)
End With
Next iCtr
End With
End Sub
Sub ShowSelectSheetsForm()
frmSelectSheets.Show
End Sub

Now save this as an addin (*.xla).

Share the workbook with her and tell her to put it in a nice safe location on
her harddrive. Then she can use Tools|addins to install that addin so that it's
available whenever she opens excel.

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm

Debra Dalgleish has some getstarted instructions for userforms at:
http://contextures.com/xlUserForm01.html

I've saved a file with this junk in it if you want to look at it:
http://www.savefile.com/files/6765686

It's usually best to disable macros (set security to high or choose not to
enable macros) when you open a workbook from an unknown sender.

Lots of things can be done that are malicious. So you should save the file,
open it, review it for bad things, then if you're happy, close the file and
reopen it with macros enabled.



Steve Vincent wrote:

I have a user who has only one arm. How can she select multiple sheets in
Excel? I know that she can right-click a sheet tab and choose "Select all
sheets". But how can she select non-adjacent sheets? She can't use Ctrl +
Click to select the sheets, as that would require the use of two hands. Does
anyone know a command that would help her?

Thanks very much in advance,

Steve Vincent

--

Dave Peterson