How many of those IDs do you have?

If there's not too many, maybe you could use a hyperlink that points at that
other location.
(Insert|Hyperlink)

If I had lots of IDs, I'd put a button from the forms toolbar in Row 1 (and
freeze row 1 so that it's always visible when I scroll up/down the worksheet).

Then I'd assign a macro to that button that worked off the location of the
active cell.

Option Explicit
Sub testme()

Dim myRng As Range
Dim myCell As Range
Dim myCol As Long
Dim myDepCol As Long
Dim DepWks As Worksheet
Dim res As Variant

'Change these
Set DepWks = Worksheets("dependent") 'what's the name
myCol = 1 'column A
myDepCol = 2 'Column B

Set myCell = ActiveSheet.Cells(ActiveCell.Row, myCol)

res = Application.Match(myCell.Value, DepWks.Columns(myDepCol), 0)

If IsError(res) Then
MsgBox ActiveCell.Value & " wasn't found on " & DepWks.Name
Else
Application.Goto DepWks.Cells(res, myDepCol), scroll:=True
End If

End Sub

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm

Gina O'Brien wrote:

Can it be done?!

I have a master spreadsheet which has a column called 'Corp Risk ID' which
consists of numbers 1,2,3 etc - I then have a dependant spreadsheet which
has a corresponding column called 'Corp Risk ID' so that I can compare how
that 'Corp Risk ID' is used in both spreadsheets (run reports, see patterns
of themes etc).

For ease when I'm presenting this dependent spreadsheet, I would love
to be able to click on a cell in the 'Corp Risk ID' column of the dependent
spreadsheet and for it to take me to its corresponding cell in the
'Corp Risk ID' column of the master spreadsheet - has anybody else
attempted this?!

Gina.

--

Dave Peterson