Now THAT is 'WAY BEYOND COOL!!!...........thanks for sharing that Don, and
thanks to Bob for the creativity........I'll get a lot of mileage out of that
one......

Vaya con Dios,
Chuck, CABGx3



"Don Guillett" wrote:

From a post by Bob Phillips

Sub RangeToGIF()
CreateImageFile _
TheExportRange:=Range("B2:e7"), _
TheFileName:="c:\a\myPic", _
TheFileFormat:="gif"


End Sub


Sub CreateImageFile(TheExportRange As Range, _
TheFileName As String, _
TheFileFormat As String)


TheExportRange.CopyPicture Appearance:=xlScreen, _
Format:=xlPicture


Dim chtobj As ChartObject
Set chtobj = TheExportRange.Parent.ChartObjects.Add(1, 1, 1, 1)


With chtobj
.Width = TheExportRange.Width + 8
.Height = TheExportRange.Height + 8
.Chart.ChartArea.Border.LineStyle = 0
.Chart.Paste
.Chart.Export Filename:=TheFileName & "." & TheFileFormat, _
FilterName:=TheFileFormat
.Delete
End With


Set chtobj = Nothing


End Sub





--
Don Guillett
SalesAid Software

"PeggyN" wrote in message
...
Is it possible to take a snapshot of an excel page and save it as a jpg,
or
to convert an excel page to a jpg file in another way?