About Us

JustinP

Thanks for your help guys. It is much appreciated.

Tom Ogilvy wrote:
This was posted by Jim Thomlinson in the past. (there have been many others
of similar ilk or using DIR)

Option Explicit
Option Compare Text

Sub test()
Call ListFiles("C:\Management", Sheet1.Range("A2"), "dbq", True)
End Sub

Public Sub ListFiles(ByVal strPath As String, _
ByVal rngDestination As Range, Optional ByVal strFileType As String = "*",
_
Optional ByVal blnSubDirectories As Boolean = False)
Dim objFSO As Scripting.FileSystemObject
Dim objFolder As Scripting.Folder
Dim objFile As Scripting.File
Dim strName As String

'Specify the file to look for...
strName = "*." & strFileType
Set objFSO = New Scripting.FileSystemObject
Set objFolder = objFSO.GetFolder(strPath)

For Each objFile In objFolder.Files
If objFile.Name Like strName Then
rngDestination.Value = objFile.Path
rngDestination.Offset(0, 1).Value = objFile.DateLastAccessed
Set rngDestination = rngDestination.Offset(1, 0)
End If
Next 'objFile
Set objFile = Nothing

'Call recursive function
If blnSubDirectories = True Then _
DoTheSubFolders objFolder.SubFolders, rngDestination, strName

Set objFSO = Nothing
Set objFolder = Nothing
End Sub

Function DoTheSubFolders(ByRef objFolders As Scripting.Folders, _
ByRef rng As Range, ByRef strTitle As String)
Dim scrFolder As Scripting.Folder
Dim scrFile As Scripting.File
Dim lngCnt As Long

On Error GoTo ErrorHandler
For Each scrFolder In objFolders
For Each scrFile In scrFolder.Files
If scrFile.Name Like strTitle Then
rng.Value = scrFile.Path
rng.Offset(0, 1).Value = scrFile.DateLastAccessed
Set rng = rng.Offset(1, 0)
End If
Next 'scrFile

'If there are more sub folders then go back and run function again.
If scrFolder.SubFolders.Count 0 Then
DoTheSubFolders scrFolder.SubFolders, rng, strTitle
End If
ErrorHandler:
Next 'scrFolder

Set scrFile = Nothing
Set scrFolder = Nothing
End Function

--

Regards,

Tom Ogilvy

"JustinP" wrote in message
ups.com...
Given a parent folder, I need to be able to search through subfolders
looking for files with the extension ".mxd" and write the name of those
files to an excel spreadsheet.

Can anyone point me in the direction of any parts of this problem being
done elsewhere? (or tell me how its done?)

Thread Tools	Search this Thread
Show Printable Version	Search this Thread: Advanced Search
Display Modes
Switch to Linear Mode Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
SubFolders in macro	pianoman[_4_]	Excel Programming	2	April 28th 06 03:25 PM
Auto look through subfolders	grewpp	Charts and Charting in Excel	1	February 14th 06 02:35 PM
copy subfolders, replace text in files and save files in copied subfolders	pieros	Excel Programming	0	November 1st 05 12:08 PM
file search in subfolders	Pflugs	Excel Programming	2	September 16th 05 05:00 AM
Get list of subfolders	Darren Hill[_3_]	Excel Programming	3	March 6th 05 09:28 PM

Menu

About Us