You can use some formulas to create a single row of data out of the
"block" of 3 lines per address. The formulas below assume that your
data list begins in B3 and that the name will be split into F3,
Address into G3, City/State/Zip into H3.

In F3, enter

=OFFSET($B$3,(3*(ROW()-ROW(F$3)))+(COLUMN()-COLUMN($F3)),0,1,1)

Fill this across to fill F3:H3. Then, to split apart the
city/state/zip field in H3 into 3 columns, enter

=LEFT(H3,FIND(",",H3,1)-1)
in I3,

=MID(H3,FIND(",",H3,1)+2,FIND(",",H3,FIND(",",H3,1 )+1)-FIND(",",H3,1)-2)
in J3

=MID(H3,FIND(",",H3,FIND(",",H3,1)+1)+2,99)
in K3.

Now, select cells F3:K3, select down the rows of the sheet for as many
"blocks" of addresses you have, and Fill Down from the Edit menu.

Now, you'll have all elements in separate columns.

See http://www.cpearson.com/excel/ColumnToTable.aspx for more
information.

Cordially,
Chip Pearson
Microsoft MVP
Excel Product Group
Pearson Software Consulting, LLC
www.cpearson.com
(email on web site)




On Fri, 21 Nov 2008 12:11:01 -0800, David
wrote:

Similar to the "convert columns to rows" question, I have a mass of data in
this format:

Name
Address
City, State, ZIP

I need to convert this info into columns so I can then import it into my
contact management program.

Any thoughts?