I am trying to insert a whole column of check boxes into an excell spread
sheet. I have figured out how to do one check box at a time. But if i try to
just copy and paste into the column it only copies it to the first selected
cell in the column.

Saved from a previous post:

Here are two subroutines. The first one adds a bunch of checkboxes from the
Forms toolbar to a range in the activesheet (b3:B10).

The second one is the one that would do what you want to do when you
check/uncheck that box. It may not be necessary. If you don't need it, then
delete that procedure and comment out this line:

..OnAction = "'" & ThisWorkbook.Name & "'!dothework"

The first one only needs to be run once--to set up the checkboxes on the
worksheet.

Option Explicit
Sub testme()

Dim myCBX As CheckBox
Dim myCell As Range

With ActiveSheet
.CheckBoxes.Delete
For Each myCell In ActiveSheet.Range("B3:B10").Cells

With myCell
Set myCBX = .Parent.CheckBoxes.Add _
(Top:=.Top, Width:=.Width, _
Left:=.Left, Height:=.Height)
With myCBX
.LinkedCell = myCell.Address(external:=True)
.Caption = ""
.Name = "CBX_" & myCell.Address(0, 0)
.OnAction = "'" & ThisWorkbook.Name & "'!dothework"
End With
.NumberFormat = ";;;"
End With

Next myCell
End With
End Sub

Sub DoTheWork()
Dim myCBX As CheckBox
Set myCBX = ActiveSheet.CheckBoxes(Application.Caller)

If myCBX = xlOn Then
'do something
Else
'do something else
End If

End Sub

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm

Craig wrote:

I am trying to insert a whole column of check boxes into an excell spread
sheet. I have figured out how to do one check box at a time. But if i try to
just copy and paste into the column it only copies it to the first selected
cell in the column.

--

Dave Peterson

Craig

Place one checkbox in the top cell of the column you want to have filled
with the check boxes. Goto the lower right corner of the cell until you get
the small + and just drag down as far as you want the checkboxes.

Mike Rogers
Hope this Helps

"Craig" wrote:

I am trying to insert a whole column of check boxes into an excell spread
sheet. I have figured out how to do one check box at a time. But if i try to
just copy and paste into the column it only copies it to the first selected
cell in the column.