Saved from a previous post:

If you want exact matches for just two columns (and return a value from a
third), you could use:

=index(othersheet!$c$1:$c$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100),0))

(all in one cell)

This is an array formula. Hit ctrl-shift-enter instead of enter. If you do it
correctly, excel will wrap curly brackets {} around your formula. (don't type
them yourself.)

Adjust the range to match--but you can only use the whole column in xl2007.

This returns the value in othersheet column C when column A and B (of
othersheet) match A2 and B2 of the sheet with the formula.

And you can add more conditions by just adding more stuff to that product
portion of the formula:

=index(othersheet!$d$1:$d$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100)
*(c2=othersheet!$c$1:$c$100),0))

Ed wrote:

Hi,

If anyone can help with this, I'd be really grateful)

I have 3 columns with data:

The first, has a list of reference numbers (i.e. 00563124P) which occure
more than once, the second has a list of text values and the third has a list
of text values.

I want to use two reference values:

The first will equate to one of the ref numbers in the first column, the
second will equate to one of the text values in the second.

I'm trying to return the value from the equivalent row in the third column
where the reference values match the data (on the same row) for the first and
second columns.

A traditional lookup won't do it and I'm a bit stuck...

Cheers,

Ed.

--

Dave Peterson