Saved from a previous post--you'll have to change your addresses:
Option Explicit
Sub testme01()
Dim historyWks As Worksheet
Dim inputWks As Worksheet
Dim nextRow As Long
Dim oCol As Long
Dim myRng As Range
Dim myAddresses As String
Dim myCell As Range
myAddresses = "A1,F9,A2,B1"
Set inputWks = Worksheets("Input")
Set historyWks = Worksheets("Summary")
With historyWks
nextRow = .Cells(.Rows.Count, "A").End(xlUp).Offset(1, 0).Row
End With
With inputWks
Set myRng = .Range(myAddresses)
If Application.CountA(myRng) < myRng.Cells.Count Then
MsgBox "Please fill in all the cells!"
Exit Sub
End If
End With
With historyWks
With .Cells(nextRow, "A")
.Value = Now
.NumberFormat = "mm/dd/yyyy hh:mm:ss"
End With
.Cells(nextRow, "B").Value = Application.UserName
oCol = 3
For Each myCell In myRng.Cells
historyWks.Cells(nextRow, oCol).Value = myCell.Value
myCell.ClearContents 'clean it up???
oCol = oCol + 1
Next myCell
End With
End Sub
I check to see if all the cells have something in them (maybe not required???).
I also add the date/time to column A of the summary sheet and the username
(taken from Tools|options|General tab) to column B.
Then Column C to xxxx go in the same order as the addresses you've specified in
this line:
myAddresses = "A1,F9,A2,B1"
(Change that to match your input worksheet.
(mycell.clearcontents may not be necessary, too.)
If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm
ScottO wrote:
Do a search in Excel help using "Excel Template Wizard". That should
give you exactly what you're looking for.
Rgds,
ScottO
"famdamly"
wrote in message
...
|
| I want to have forms that I design in one work sheet. Then I want
the
| data that is input into the forms to be compiled into a data base
| automatically.
|
|
| --
| famdamly
| -------------------------------------------------------------------
-----
| famdamly's Profile:
http://www.excelforum.com/member.php...o&userid=29382
| View this thread:
http://www.excelforum.com/showthread...hreadid=492635
|
--
Dave Peterson