I just received a spreadsheet from a sales rep where every entry is in ALL
CAPS. How do I get it to do proper case throughout the spreadsheet?

Use another spreadsheet. In A1 type
=PROPER(
switch spreadsheets and click on A1 of the original. Then close
parentheses. Copy throughout. Then, the get rid of formulas,
Copy everything, Edit!Paste Special... and check Values.

HTH
Kostis Vezerides

Look here

http://www.mvps.org/dmcritchie/excel/proper.htm
Or
http://www.cpearson.com/excel/case.htm


Here are some Macro's for changing text cells in the selection

Sub Uppercase_macro()
Dim selectie As Range
Dim cel As Range
On Error Resume Next
Set selectie = Range(ActiveCell.Address & "," & Selection.Address) _
.SpecialCells(xlCellTypeConstants, xlTextValues)
If selectie Is Nothing Then Exit Sub
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
For Each cel In selectie
cel.Value = UCase(cel.Value)
Next cel
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub


Sub Lowercase_macro()
Dim selectie As Range
Dim cel As Range
On Error Resume Next
Set selectie = Range(ActiveCell.Address & "," & Selection.Address) _
.SpecialCells(xlCellTypeConstants, xlTextValues)
If selectie Is Nothing Then Exit Sub
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
For Each cel In selectie
cel.Value = LCase(cel.Value)
Next cel
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub


Sub Propercase_macro()
Dim selectie As Range
Dim cel As Range
On Error Resume Next
Set selectie = Range(ActiveCell.Address & "," & Selection.Address) _
.SpecialCells(xlCellTypeConstants, xlTextValues)
If selectie Is Nothing Then Exit Sub
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
For Each cel In selectie
cel.Value = StrConv(cel.Value, vbProperCase)
Next cel
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub


--
Regards Ron de Bruin
http://www.rondebruin.nl


"Moosieb" wrote in message ...
I just received a spreadsheet from a sales rep where every entry is in ALL
CAPS. How do I get it to do proper case throughout the spreadsheet?

Hi,

You may want to download ASAP utilities to accomplish this task.

Regards,

"Moosieb" wrote:

I just received a spreadsheet from a sales rep where every entry is in ALL
CAPS. How do I get it to do proper case throughout the spreadsheet?