I have Sheet1 with the following info:
A B C
1 0001
2 0002
3 0003
4


Then I have Sheet2 with the following information:

A B C
1 0001 Switch-1 10.13.6.1
2 0001 Switch-2 10.13.6.2
3 0001 Router-1 10.13.6.3
4 0001 Router-2 10.13.6.4
5 0002 Switch-1 10.13.7.1
6 0002 Switch-2 10.13.7.2
7 0002 Router-1 10.13.7.3
8 0002 Router-2 10.13.7.4
9 0003 Switch-1 10.13.8.1
10 0003 Switch-2 10.13.8.2
11 0003 Router-1 10.13.8.3
12 0003 Router-2 10.13.8.4

I want Sheet1 in Column B to display the IP address of the matching site on
Column A (ex: 0001) for Router-1 from Sheet2.

Thanks in advance!

Saved from a previous post:

If you want exact matches for just two columns (and return a value from a
third), you could use:

=index(othersheet!$c$1:$c$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100),0))

(all in one cell)

This is an array formula. Hit ctrl-shift-enter instead of enter. If you do it
correctly, excel will wrap curly brackets {} around your formula. (don't type
them yourself.)

Adjust the range to match--but you can only use the whole column in xl2007.

This returns the value in othersheet column C when column A and B (of
othersheet) match A2 and B2 of the sheet with the formula.

And you can add more conditions by just adding more stuff to that product
portion of the formula:

=index(othersheet!$d$1:$d$100,
match(1,(a2=othersheet!$a$1:$a$100)
*(b2=othersheet!$b$1:$b$100)
*(c2=othersheet!$c$1:$c$100),0))

============
If there is only one match and you're bringing back a number (or 0 if there is
no match for all the criteria), you can use:

=sumproduct(--(othersheet!a1:a10=a1),
--(othersheet!b1:b10=b1),
(othersheet!c1:c10))

Or if you want to include the "router-1" in the formula:

=sumproduct(--(othersheet!a1:a10=a1),
--(othersheet!b1:b10="router-1"),
(othersheet!c1:c10))

Adjust the ranges to match--but you can't use whole columns (except in xl2007).

=sumproduct() likes to work with numbers. The -- stuff changes trues and falses
to 1's and 0's.

Bob Phillips explains =sumproduct() in much more detail he
http://www.xldynamic.com/source/xld.SUMPRODUCT.html

And J.E. McGimpsey has some notes at:
http://mcgimpsey.com/excel/formulae/doubleneg.html

Goad wrote:

I have Sheet1 with the following info:
A B C
1 0001
2 0002
3 0003
4

Then I have Sheet2 with the following information:

A B C
1 0001 Switch-1 10.13.6.1
2 0001 Switch-2 10.13.6.2
3 0001 Router-1 10.13.6.3
4 0001 Router-2 10.13.6.4
5 0002 Switch-1 10.13.7.1
6 0002 Switch-2 10.13.7.2
7 0002 Router-1 10.13.7.3
8 0002 Router-2 10.13.7.4
9 0003 Switch-1 10.13.8.1
10 0003 Switch-2 10.13.8.2
11 0003 Router-1 10.13.8.3
12 0003 Router-2 10.13.8.4

I want Sheet1 in Column B to display the IP address of the matching site on
Column A (ex: 0001) for Router-1 from Sheet2.

Thanks in advance!

--

Dave Peterson

Not sure what you're talking about, but check this out:
http://www.contextures.com/xlFunctions03.html

Post back if that suggestion doesn't work...there are many ways to skin a
cat...

Hope that helps,
Ryan--

--
Ryan---
If this information was helpful, please indicate this by clicking ''Yes''.


"Goad" wrote:

I have Sheet1 with the following info:
A B C
1 0001
2 0002
3 0003
4


Then I have Sheet2 with the following information:

A B C
1 0001 Switch-1 10.13.6.1
2 0001 Switch-2 10.13.6.2
3 0001 Router-1 10.13.6.3
4 0001 Router-2 10.13.6.4
5 0002 Switch-1 10.13.7.1
6 0002 Switch-2 10.13.7.2
7 0002 Router-1 10.13.7.3
8 0002 Router-2 10.13.7.4
9 0003 Switch-1 10.13.8.1
10 0003 Switch-2 10.13.8.2
11 0003 Router-1 10.13.8.3
12 0003 Router-2 10.13.8.4

I want Sheet1 in Column B to display the IP address of the matching site on
Column A (ex: 0001) for Router-1 from Sheet2.

Thanks in advance!