One more option since this was posted in the functions group...
Use an array formula which sums every combination of values
(for 16 values there are 2^16=65536 combinations)

Suppose your values are in A2:A17 and A1=22000, B1=1.
Select B2:B17 and enter the formula below with CTRL+SHIFT+ENTER:
(Other solutions are easily found by setting B1=2,3,...)

=MOD(MOD(SMALL(ABS(ROUND((
(MOD(ROW(A:A)/2^0,2)=1)*A2+
(MOD(ROW(A:A)/2^1,2)=1)*A3+
(MOD(ROW(A:A)/2^2,2)=1)*A4+
(MOD(ROW(A:A)/2^3,2)=1)*A5+
(MOD(ROW(A:A)/2^4,2)=1)*A6+
(MOD(ROW(A:A)/2^5,2)=1)*A7+
(MOD(ROW(A:A)/2^6,2)=1)*A8+
(MOD(ROW(A:A)/2^7,2)=1)*A9+
(MOD(ROW(A:A)/2^8,2)=1)*A10+
(MOD(ROW(A:A)/2^9,2)=1)*A11+
(MOD(ROW(A:A)/2^10,2)=1)*A12+
(MOD(ROW(A:A)/2^11,2)=1)*A13+
(MOD(ROW(A:A)/2^12,2)=1)*A14+
(MOD(ROW(A:A)/2^13,2)=1)*A15+
(MOD(ROW(A:A)/2^14,2)=1)*A16+
(MOD(ROW(A:A)/2^15,2)=1)*A17
-A1)*10^8,-6))+ROW(A:A),B1),10^6)/2
^{0;1;2;3;4;5;6;7;8;9;10;11;12;13;14;15},2)=1

This returns TRUE or FALSE next to each value to include in the sum,

"KUNA" wrote:

Is there a formula or look up function within excel that will do the following:

Locate within a range of cells the cells that when summed together equal a
specified amount.

For example: I am looking for 22,000 amount that is a combination of the
records within a range of cells.

Will excel show me the possible results even if it were many?

Help and thanks.