On Wed, 16 Mar 2005 04:33:01 -0800, Lindsey M
wrote:

Hi

Say I have the following in cell G3:

15.02.05 11:09:52 Stevens Feb 22 2005 Lindsey Martin

I want A3 = 15.02.05 11:09:52 (so i use =LEFT(G3,17)
I want B3 = Stevens (so I've used =MID(G3, 19, 8) and this works, problem
is, the name won't always be 8 chars long, so is there any way that I can set
it so that it counts all chars of the name until it comes to the space and
then inserts that?
I want C3 = Feb 22 2005, i haven't worked this one out yet because I'm
assuming that once B3 is sorted, it will work around that?
And finally, D3 = Lindsey Martin. I know I can use the RIGHT function for
this one, but again, the chars of this one will differ (eg Claire Dunn
instead of Lindsey Martin), any ideas on this one?

Any help would be greatly appreciated

Cheers
Linds


A3:

=LEFT(TRIM(G3),FIND(CHAR(1),
SUBSTITUTE(TRIM(G3)," ",CHAR(1),2))-1)

B3:

=MID(TRIM(G3),FIND(CHAR(1),SUBSTITUTE(TRIM(G3)," ",
CHAR(1),2))+1,FIND(CHAR(1),SUBSTITUTE(TRIM(G3)," ",
CHAR(1),3))-FIND(CHAR(1),SUBSTITUTE(TRIM(G3)," ",CHAR(1),2))-1)

C3:

=MID(TRIM(G3),FIND(CHAR(1),SUBSTITUTE(TRIM(G3)," ",
CHAR(1),3))+1,FIND(CHAR(1),SUBSTITUTE(TRIM(G3)," ",
CHAR(1),6))-FIND(CHAR(1),SUBSTITUTE(TRIM(G3)," ",CHAR(1),3))-1)

D3:

=MID(TRIM(G3),FIND(CHAR(1),SUBSTITUTE(TRIM(G3)," ",
CHAR(1),6))+1,255)


--ron