About Us

Kumar

Thanks for your help.

Kumar.

(Jamie Collins) wrote in message om...
(Kumar) wrote ...

Is there a way where I can get a list of distinct values for a column
from a set of rows which is obtained by applying a set of filter
parameters (basically equivalent of a select distinct in SQL)?
Is there
a function/formula which could extract a subset of rows into another
range? (e.g., like SELECT in SQL.)

Perhaps you want to use sql sytax:

Option Explicit

Sub test()
CopyToNewWorksheet "Sheet1"
End Sub

Private Function CopyToNewWorksheet( _
ByVal SheetName As String, _
Optional ByVal NewSheetName As String _
) As Boolean

Dim wb As Excel.Workbook
Dim ws As Excel.Worksheet
Dim Target As Excel.Range
Dim Con As Object
Dim rs As Object
Dim strCon As String
Dim strPath As String
Dim strSql1 As String
Dim lngCounter As Long

' Review the following constant:
Const FILENAME_XL_TEMP As String = "" & _
"delete_me.xls"

' Do NOT amend the following constants
Const CONN_STRING As String = "" & _
"Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=<PATH<FILENAME;" & _
"Extended Properties='Excel 8.0;HDR=YES'"

Const SQL As String = "" & _
"SELECT DISTINCT * FROM [<SHEET_NAME$]"

' Build connection string
strPath = ThisWorkbook.Path & _
Application.PathSeparator

strCon = CONN_STRING
strCon = Replace(strCon, _
"<PATH", strPath)
strCon = Replace(strCon, _
"<FILENAME", FILENAME_XL_TEMP)

' Build sql statement
strSql1 = SQL
strSql1 = Replace(strSql1, _
"<SHEET_NAME", SheetName)

' Delete old instance of temp workbook
On Error Resume Next
Kill strPath & FILENAME_XL_TEMP
On Error GoTo 0

' Save copy of worksheet to temp workbook
Set wb = Excel.Application.Workbooks.Add()
With wb
ThisWorkbook.Worksheets(SheetName). _
Copy .Worksheets(1)

.SaveAs strPath & FILENAME_XL_TEMP
.Close
End With

' Open connection to temp workbook
Set Con = CreateObject("ADODB.Connection")
With Con
.ConnectionString = strCon
.Open

Set rs = .Execute(strSql1)
End With

Set ws = ThisWorkbook.Worksheets.Add
With ws
If Len(NewSheetName) 0 Then
.Name = NewSheetName
End If
Set Target = .Range("A1")
End With

With rs
For lngCounter = 1 To .fields.Count
Target(1, lngCounter).Value = _
.fields(lngCounter - 1).Name
Next
End With

Target(2, 1).CopyFromRecordset rs

Con.Close

CopyToNewWorksheet = True

End Function

Jamie.

--

Thread Tools	Search this Thread
Show Printable Version	Search this Thread: Advanced Search
Display Modes
Switch to Linear Mode Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Unique Values, not Unique Records	steph44haf	Excel Discussion (Misc queries)	1	May 12th 10 07:52 PM
"--" (was "DCOUNT Unique Values")	Wilba	Excel Worksheet Functions	2	November 3rd 07 12:50 AM
DCOUNT Unique Values	Wilba	Excel Worksheet Functions	2	October 26th 07 10:06 AM
DCOUNT to Return Values from Access database	Tim H	Excel Discussion (Misc queries)	5	December 15th 05 10:27 PM
DSUM and DCount when criteria values are similar	BAC	Excel Worksheet Functions	1	February 14th 05 06:38 PM

Menu

About Us