We are entering data in a call. We want to capture the time that the data
was entered. We have tired the now() function and the today() function, but
these change on recalculation. Can anyone think of a way to capture the time?

This puts it alongside

Private Sub Worksheet_Change(ByVal Target As Range)
Const WS_RANGE As String = "H1:H10" '<== change to suit

On Error GoTo ws_exit
Application.EnableEvents = False

If Not Intersect(Target, Me.Range(WS_RANGE)) Is Nothing Then
With Target
.Offset(0, 1).Value = Format(Now, "dd mmm yyyy hh:mm:ss")
End With
End If

ws_exit:
Application.EnableEvents = True
End Sub

'This is worksheet event code, which means that it needs to be
'placed in the appropriate worksheet code module, not a standard
'code module. To do this, right-click on the sheet tab, select
'the View Code option from the menu, and paste the code in.


--
HTH

Bob

(there's no email, no snail mail, but somewhere should be gmail in my addy)

"Mike D." wrote in message
...
We are entering data in a call. We want to capture the time that the data
was entered. We have tired the now() function and the today() function,
but
these change on recalculation. Can anyone think of a way to capture the
time?

There are several ways:-

ctrl+; for the none volatile date
CTRL+Shift+; none volatile time

or paste this code in as worksheets code (right click sheet tab, view code
and paste). It monitors A1 - a100 and when data are entered time stamps in
the B column


Private Sub Worksheet_Change(ByVal Target As Excel.Range)
With Target
If .Count 1 Then Exit Sub
If Not Intersect(Range("A1:A100"), .Cells) Is Nothing Then
Application.EnableEvents = False
If IsEmpty(.Value) Then
.Offset(0, 1).ClearContents
Else
With .Offset(0, 1)
.NumberFormat = "dd mmm yyyy hh:mm:ss"
.Value = Now
End With
End If
Application.EnableEvents = True
End If
End With
End Sub

Mike


"Mike D." wrote:

We are entering data in a call. We want to capture the time that the data
was entered. We have tired the now() function and the today() function, but
these change on recalculation. Can anyone think of a way to capture the time?