It may be pretty, but I like to just put X's in cells <bg.

"T. Valko" wrote:

I'll take the credit for realizing how useful it is and saving it and give
Dave due credit for writing it. Dave's the man!

Biff

"timmeah4" wrote in message
...
Thank you so much, this macro is awesome!

"T. Valko" wrote:

Here's a macro by Dave Peterson:

Option Explicit
Sub addCBX()
Dim myCBX As CheckBox
Dim myCell As Range

With ActiveSheet
.CheckBoxes.Delete 'nice for testing
For Each myCell In ActiveSheet.Range("a2:a10").Cells
With myCell
Set myCBX = .Parent.CheckBoxes.Add _
(Top:=.Top, Width:=.Width, _
Left:=.Left, Height:=.Height)
With myCBX
.LinkedCell = myCell.Address(external:=True)
'.Caption = "" 'or whatever you want
'.Name = "CBX_" & myCell.Address(0, 0)
End With
.NumberFormat = ";;;"
End With
Next myCell
End With
End Sub

Change the range (set to A2:A10) as needed. The macro automatically sets
the
linked cell to be the same cell the checkbox is "in". It also sets the
linked cell font format to be "invisible". If you want custom captions
for
each checkbox you have to do that manually. If you want no caption "un
REM"
the line:

'.Caption = "" 'or whatever you want

To:

..Caption = "" 'or whatever you want

Note: make sure the column is wide enough (about ~130 pixels) otherwise
the
default caption could get truncated.

Biff

"timmeah4" wrote in message
...
I am creating a large data entry excel spreadsheet and I want to be able
to
insert, probably 100+ check boxes, my problem is that I dont want to
have
to
associate every single checkbox with every single cell. is there a way
that I
can just click and drag (like fomulas do) and have the cells be
populated
by
checkboxes.

I do not want to have to right click each checkbox -- properties --
control, and then link the value to a cell.

Please help!




--

Dave Peterson