I use an excel template where I have to use merged cells because the
data being transferred too the document is too large for a single cell.
This merged cell happens to be merged horizontally and vertically. I am
able to wrap text if the entry is small, but I run into problems when
there are multiple lines of text wrapping. It seems as if there is a
limit on the number of rows excel will wrap within a specific merged
cell, but this limit may vary. I have experienced this same problem on
unmerged cells. Can anyone help?

Gord Dibben wrote:
This is event code.

Right-click on the sheet tab and "View Code"

Copy/paste the code into that module.

Notes from Greg.................

The WrapText property of the merged cells has to be set to True.

The merged cells must be merged horizontally (e.g. A2 + B2 + C2 etc.) as
opposed to vertically (e.g. A2 + A3 + A4...). If your cells are merged
vertically then the code won't work.


Gord


On Tue, 19 Sep 2006 08:14:02 -0700, Melanie
wrote:

I am having the same issue, please could you explain how to use the VBA code
below.

Thanks

Melanie

"Gord Dibben" wrote:

Winnie

Wrap text works fine on merged cells.

Your problem is...............Rows with Merged cells will not Autofit.

You need VBA code to do that.

Here is code from Greg Wilson.

Private Sub Worksheet_Change(ByVal Target As Range)
Dim NewRwHt As Single
Dim cWdth As Single, MrgeWdth As Single
Dim c As Range, cc As Range
Dim ma As Range

With Target
If .MergeCells And .WrapText Then
Set c = Target.Cells(1, 1)
cWdth = c.ColumnWidth
Set ma = c.MergeArea
For Each cc In ma.Cells
MrgeWdth = MrgeWdth + cc.ColumnWidth
Next
Application.ScreenUpdating = False
ma.MergeCells = False
c.ColumnWidth = MrgeWdth
c.EntireRow.AutoFit
NewRwHt = c.RowHeight
c.ColumnWidth = cWdth
ma.MergeCells = True
ma.RowHeight = NewRwHt
cWdth = 0: MrgeWdth = 0
Application.ScreenUpdating = True
End If
End With
End Sub


Gord Dibben MS Excel MVP

On Wed, 30 Aug 2006 22:18:01 -0700, Winnie
wrote:

When I choose Merge cells and Wrap text function in the Text control.

the Wrap text function not working in the merger cells?

Please help

Gord Dibben MS Excel MVP