SUMIF question (although, I think I'm using the wrong function
"Luke M" wrote:
=SUMPRODUCT((--(LEFT(A2:A100)=1743)*(B2:B100))
You seem to have several typos.
The double negative (--) is in there to change the text output
from the LEFT function back into a number value.
If that was your intent, you need the double negation to be adjacent to the
LEFT function, thus:
=SUMPRODUCT((--LEFT(A2:A100)=1743)*(B2:B100))
The also remedies your syntax error.
But your formula still does not make sense since the default length for LEFT
is 1 character. Perhaps you meant:
=SUMPRODUCT((--LEFT(A2:A100,4)=1743)*(B2:B100))
But why not write, more simply:
=SUMPRODUCT((LEFT(A2:A100,4)="1743")*(B2:B100))
with or without the parentheses around B2:B100.
Still, I would prefer:
=SUMPRODUCT(--(LEFT(A2:A100,4)="1743"), B2:B100)
since that avoids #VALUE errors if some of B2:B100 are non-numeric
----- original message -----
"Luke M" wrote:
You can do this with the SUMPRODUCT function. Something like:
=SUMPRODUCT((--(LEFT(A2:A100)=1743)*(B2:B100))
The double negative (--) is in there to change the text output from the LEFT
function back into a number value.
--
Best Regards,
Luke M
*Remember to click "yes" if this post helped you!*
"Ashley" wrote:
I have a 2 column log that tracks incoming call amounts from agents
identified as 6 digit numbers CCOOAA - County, Office, Agent#:
171917 4
174327 6
171629 9
174327 13
172832 5
I want to add another table that takes ONLY the first 4 digits from the 6
digit number, then adds the totals from their call amounts. IN the example
above, for 174327, it would equal 19. (13+6).
|