Here's a formulas play which presumes that there will be only a single date
with "DISC" per week

Assuming your source data as posted is in Sheet1, with dates commencing in
C29:I29, followed by C32:I32, etc (spaced at intervals of 3 rows)

In another sheet,
Place in any start cell, say in B2, normal ENTER, format B2 as date to taste:
=INDEX(OFFSET(Sheet1!C$29:I$29,ROWS($1:1)*3-3,,),MATCH(TRUE,INDEX(OFFSET(Sheet1!C$29:I$29,ROWS ($1:1)*3-2,,)="DISC",),0))
Copy B2 down as far as required. B2 returns the 1st week's date for the
DISC, B3 returns the 2nd week's date, and so on.

Perhaps better with an IF(ISNA(..) error trap to return neat looking blanks
for any week without a DISC, use this instead in B2, normal ENTER:
=IF(ISNA(MATCH(TRUE,INDEX(OFFSET(Sheet1!C$29:I$29, ROWS($1:1)*3-2,,)="DISC",),0)),"",INDEX(OFFSET(Sheet1!C$29:I$29 ,ROWS($1:1)*3-3,,),MATCH(TRUE,INDEX(OFFSET(Sheet1!C$29:I$29,ROWS ($1:1)*3-2,,)="DISC",),0)))

Above helps? hit the YES below
--
Max
Singapore
http://savefile.com/projects/236895
Downloads:27,000 Files:200 Subscribers:70
xdemechanik
---
"Eric_in_EVV" wrote:
I have a spreadsheet that looks like this:

C D E F G
H I
row 29 18-Jan 19-Jan 20-Jan 21-Jan 22-Jan 23-Jan
24- Jan
row 30 DISC
row 31 ed
row 32 25-Jan 26-Jan 27-Jan 28-Jan 29-Jan 30-Jan
31- Jan
row 33 DISC
row 34 ed

What I need to be able to do is search for each occurance of the "DISC" and
then use the date (the cell above the "DISC") on a different worksheet in the
workbook that contains summary information. I need to be able to report each
date that the "DISC" code occurs.

I hope this all makes sense !

Thanks in advance for any suggestions !