Try the below array formula and copy down as required...which will return the
employee names in Sheet1 ColA which have and 'Yes' in Col F

=IF(COUNTIF([A.XLS]Sheet1!$F$1:$F$100,"Yes")<ROW(A1),"",
INDEX([A.XLS]Sheet1!A$1:A$100,SMALL(IF([A.XLS]Sheet1!$F$1:$F$100="Yes",
ROW([A.XLS]Sheet1!$F$1:$F$100)),ROW(A1))))

Please note that this is an array formula. You create array formulas in the
same way that you create other formulas, except you press CTRL+SHIFT+ENTER to
enter the formula. If successful in 'Formula Bar' you can notice the curly
braces at both ends like "{=<formula}"

If this post helps click Yes
---------------
Jacob Skaria


"Frustrated" wrote:

That worked but can this formula work for a range of cells in Column F? I
have not been able to get it to work for a range of cells. So say i have 7
employee's that answer yes and 8 employees that answer no i only want to pull
the employee's that answer yes. Can this be done?

"Jacob Skaria" wrote:

Do you mean

=IF([A.XLS]Sheet1!F1="YES",[A.XLS]Sheet1!A1,"")

If this post helps click Yes
---------------
Jacob Skaria


"Frustrated" wrote:

I need a little help. I need to pull data from one excel workbook (A) and
display the data on another excel workbook (B) but i only want to pull the
date if in workbook (A) cell F is yes. If document (A) cell F is no then i do
not want to pull the data to workbook (B). Can this be done?