Try this...

Data in the range Sheet1A2:B9

Enter this array formula** on Sheet2 A2:

=INDEX(Sheet1!A$2:A$9,MATCH(LARGE(Sheet1!B$2:B$9-ROW(Sheet1!B$2:B$9)/10^10,ROWS(A$2:A2)),Sheet1!B$2:B$9-ROW(Sheet1!B$2:B$9)/10^10,0))

** array formulas need to be entered using the key combination of
CTRL,SHIFT,ENTER (not just ENTER). Hold down both the CTRL key and the SHIFT
key then hit ENTER.

Enter this formula on Sheet2 B2:

=SUMIF(Sheet1!A$2:A$9,A2,Sheet1!B$2:B$9)

Format as Percentage

Select both A2 and B2 and copy down to A9:B9.

--
Biff
Microsoft Excel MVP


"Commish" wrote in message
...
On Jul 17, 4:24 pm, Luke M wrote:
On sheet1, create a helper column (I'll assume column C), with this
formula
entered in row 2 and copied down:
=RANK(B2,$B$2:$B$6)+IF(COUNTIF($C$1:C1,RANK(B2,$B$ 2:$B$6))0,1,0)

On sheet2, A2 formula is:
=INDEX(Sheet1!A$2:A$100,MATCH(ROW(Sheet1!$A1),Shee t1!$C$2:$C$100,0))

Copy down as needed, and across 1 column.
--
Best Regards,

Luke M
*Remember to click "yes" if this post helped you!*

"Basenji" wrote:
On sheet 1 in column A is the name of the account; same sheet column B
is a
percentage.

Account Percentage
Mercy 80.4%
Henry 89.6%
Fred 0.00%
Chris 92.70%
Connie 92.00%
Alex 92.60%
Larry 89.80%
Ollie 0.00%

On a second sheet (a summary sheet) a formula is needed to sort
andrankthe
accounts so that the account with the highest percentage is at the top
of the
list, like this,

Chris 92.70%
Alex 92.60%
Connie 92.00%
etc

I have tried a combination of formulas but have been unsuccessful.
Thank you.

This works well when there are at most 2 equal values in the range -
what if there are more than 3 or four?