Use this macro from Bernie Deitrick.

If you're new to macros: instructions at the end of the post

--
Kind regards,

Niek Otten
Microsoft MVP - Excel



' ================================================== =========
' Importing a large file into Excel. File MAY have more than 65,000 records
' and will automatically start a new sheet.


Sub LargeFileImport()
'Bernie Deitrick's code for opening very large text files in Excel
'Dimension Variables
Dim ResultStr As String
Dim FileName As String
Dim FileNum As Integer
Dim Counter As Double
'Ask User for File's Name
FileName = Application.GetOpenFilename
'Check for no entry
If FileName = "" Then End
'Get Next Available File Handle Number
FileNum = FreeFile()
'Open Text File For Input
Open FileName For Input As #FileNum
'Turn Screen Updating Off
Application.ScreenUpdating = False
'Create A New WorkBook With One Worksheet In It
Workbooks.Add Template:=xlWorksheet
'Set The Counter to 1
Counter = 1
'Loop Until the End Of File Is Reached
Do While Seek(FileNum) <= LOF(FileNum)
'Display Importing Row Number On Status Bar
Application.StatusBar = "Importing Row " & Counter & " of text file " _
& FileName
'Store One Line Of Text From File To Variable
Line Input #FileNum, ResultStr
'Store Variable Data Into Active Cell
If Left(ResultStr, 1) = "=" Then
ActiveCell.Value = "'" & ResultStr
Else
ActiveCell.Value = ResultStr
End If
If ActiveCell.Row = 65536 Then
'If On The Last Row Then Add A New Sheet
ActiveWorkbook.Sheets.Add
Else
'If Not The Last Row Then Go One Cell Down
ActiveCell.Offset(1, 0).Select
End If
'Increment the Counter By 1
Counter = Counter + 1
'Start Again At Top Of 'Do While' Statement
Loop
'Close The Open Text File
Close
'Remove Message From Status Bar
Application.StatusBar = False
End Sub

' ================================================== =========

Copy the text of the macro
Go to Excel
Press ALT+F11; this starts the VB Editor
InsertModule
Paste the macro into the module
Press ALT+F11 to return to Excel
Run the macro from the ToolsMacro menu



"SteveGuno" wrote in message ...
|I need to download some Data that contains more than 65,530 Rows. Is there a
| way to do this??? Increase the number of rows or have the data entered on
| more that one worksheet???