=INDEX($B$1:$B$10,SMALL(IF($A$1:$A$10=$C$1,ROW($B$ 1:$B$10)-ROW($B$1)+1),ROW(A1)))

Try this:

C1 = ASIH
C2 = BB

Array entered** in D1:

=INDEX(A$1:A$7,SMALL(IF(($A$1:$A$7=$C$1)+($A$1:$A$ 7=$C$2),ROW(A$1:A$7)-MIN(ROW(A$1:A$7))+1),ROWS(D$1:D1)))

Copy across to E1 then down until you get #NUM! errors meaning all the
relative data has been extracted.

** array formulas need to be entered using the key combination of
CTRL,SHIFT,ENTER (not just ENTER)

--
Biff
Microsoft Excel MVP


"pierre" wrote in message
...
SUPPOSE now , i have the following data :

A B
1 ASIH 234
2 aa 334
3 BB 434
4 ASIH 534
5 cc 634
6 BB 734
7 ASIH 834


suppose i want to have the results of "asih" and " BB"...how to edit the
formula :

=INDEX($B$1:$B$10,SMALL(IF($A$1:$A$10=$C$1,ROW($B$ 1:$B$10)-ROW($B$1)+1),ROW(A1)))

PLEASE HELP



"Mike H" wrote:

Hi,

With your search string in C1 Try this in D1 and drag down 3 rows

=INDEX($B$1:$B$10,SMALL(IF($A$1:$A$10=$C$1,ROW($B$ 1:$B$10)-ROW($B$1)+1),ROW(A1)))

It's an array so commit with CTRL+Shift+Enter

Mike

"pierre" wrote:

i have the following given :

A B
1 asih 234
2 aa 334
3 bb 434
4 asih 534
5 cc 634
6 dd 734
7 asih 834

i managed to do the following :
{INDEX($A$1:$B$7,SMALL(IF($A$1:$A$7=C1,ROW($A$1:$A $7)),ROW(1:1)),2)}
and i dragged it to cell C3.
NOW.....
my purpose for this is to be able TO enter the word "asih" in C1 and C2
and
C3 in order to be able its coresponding data which are : 234 , 534 ,
834
MY QUESTION NOW IS :
what should i do to insert the following formula :
index(....),match(....) )
WITHIN THE PRECEDENT FORMULA:
{INDEX($A$1:$B$7,SMALL(IF($A$1:$A$7=C1,ROW($A$1:$A $7)),ROW(1:1)),2)}
AND THAT IN ORDER TO GET FOR EXAMPLE (734) IF I HAD TO TYPE
(DD).????

THANKS FOR YOUR HELP