Wow, Thank You very much.. That is exactly what I am looking for..

"Ron Coderre" wrote:

Perhaps a slightly different approach...

With A1:B5 containing this list:
a 20
b 25
c 30
d 35
e 25

Then
D1: =LARGE($B$1:$B$5,ROW())
Copy that formula down through D5

Put this ARRAY FORMULA (committed with Ctrl+shift+enter, instead of just
enter) in
C1:
=INDEX($A$1:$A$10,SMALL(IF($B$1:$B$10=$D1,ROW($B$1 :$B$10)),COUNTIF(D$1:D1,D1)))

Copy C1 and paste into C2:C5

However, if your first row contains column headings (like this)
Name Number
a 20
b 25
c 30
d 35
e 25

Then these formula adjust for data not starting at Row_1
D1: Grade
D2: =LARGE($B$2:$B$6,ROW()-ROW($D$1))
Copy down

C1: RankName
And put this ARRAY FORMULA in
C2:
=INDEX($A$2:$A$11,SMALL(IF($B$2:$B$11=$D2,ROW($B$2 :$B$11)-ROWS($B$1:$B$1)),COUNTIF(D$2:D2,D2)))

Copy C2 and paste into C3:C6

Does that help?
***********
Regards,
Ron

XL2002, WinXP


"emarzuq" wrote:

Hello,

I have a list

A B
1 a 20
2 b 25
3 c 30
4 d 35
5 e 25

I would like to be able to have column C to list column a from largest to
smallest and column D to list the associated numbers with that. Taking into
consideration that a b and e have the same value. So what I am looking for
will look like this

C D
1 d 35
2 c 30
3 b 25
4 e 25
5 a 20

Can anyone help. I believe it will have to be an index match formula of
some sort but I am not sure how to procede.

Thanks in advance,

Eyad