Hi


I think you have a mistake with your table, as there is a "hole" between
5400 and 6000 where no tax would be paid.
Cumulatively until the end of the 12% band it is 2700, and the 15% band
needs to be 3300 to reach the final band of 6000

You could do it all in one cell with the following formula
=MIN(A1-150,150)*5%+MAX(0,MIN(A1-300,300))*10%+
MAX(0,MIN(A1-600,2100))*12%+MAX(0,MIN(A1-2700,3300))*15%+
MAX(0,A1-6000)*30%

Or if you wanted to see it set out as a table then
in cells E4 to E9 enter 150,300,600,2700,6000, Over 6000
in cells G4 to G9 enter 0%,5%,10%,12%,15%,30%
in cell F4 enter
=MIN(E4,$A$1)-F3
and copy down to cell F9
in cell H4 enter
=F4*G4 and copy down to H9

In F10 enter = SUM(F4:F9)
in H10 = SUM(H4:H9)

In both cases enter salary figure in cell A1
--
Regards

Roger Govier


"Darkwah" wrote in message
...
I have a simple spreadsheet for calculating salaries of workers of a
small
business. I have a long nested IF expression for calculating the
income tax
component. It is working but it is too long and not easy to edit. Is
there
any way out?
Assumption:
Income Rate
First $150 0%
Next $150 5%
Next $300 10%
Next $2,100 12%
Next $2,700 15%
Exceeding $6,000 30%

Could anyone be of help?
Thank you

Darkwah