If you only have 2 sheets involved:

=COUNTIF('43-03951804'!A5,"x")+COUNTIF('80-06069282'!A5,"x")

Biff

"Laffin" wrote in message
...
Perfect! Thank you so much!

"Peo Sjoblom" wrote:

If you only have 2 sheets you can hardcode the name into the formula like
this

=SUMPRODUCT(COUNTIF(INDIRECT("'"&{"43-03951804";"80-06069282"}&"'!A5"),"x"))


obviously if you had 30 sheets the formula would get out of hand
hardcoded


--
Regards,

Peo Sjoblom



"Laffin" wrote in message
...
Your recommendation of putting the sheet names in a range of cells
worked
for
me. Thank you so much for that. However, since most of my sheets will
not
likely have a pattern, if I only had two sheets I wanted to use and the
names
were 43-03951804 and 80-06069282, how would I write the formula without
putting them in a range?

"Peo Sjoblom" wrote:

Are the sheets named like name1. name2 and so on? If so use

=SUMPRODUCT(COUNTIF(INDIRECT("'Name"&{1;2;3;4;5;6; 7;8;9}&"'!A5"),"x"))

replace Name with whatever name you use for the sheets

however if each name is not in a patter like the above the easiest
way
is
to put all sheets name in a range, for instance if you put then in
H1:H9
in
the summary sheet,

then you can use

=SUMPRODUCT(COUNTIF(INDIRECT("'"&H1:H9&"'!A5"),"x" ))


or select H1:H9, do insertnamedefine and give it a name like
MySheets, then you can use


=SUMPRODUCT(COUNTIF(INDIRECT("'"&MySheets&"'!A5"), "x"))


--
Regards,

Peo Sjoblom



"Laffin" wrote in message
...
I have a workbook with several sheets. I am trying to determine how
many
times "x" appears - using a specific cell (A5) as my reference in
each
of
the sheets. I want to count how many times "x" appears in cell A5
within
all
the worksheets and summarize on a summary worksheet. So, if I have
9
worksheets that I want to count, I want to know that "x" appears in
only 7
of
the worksheets.