Saved from a previous post:

Are you asking about the custom lists that you see in that dialog?

If yes, you can modify those lists manually via: Tools|Options|Custom lists

You could use a couple of macros, too.

The first exports the lists to a new worksheet.

Then save the workbook and open it on a different pc.

The second imports those extracted lists into excel on the new pc.

Option Explicit
Sub ExtractCustomList()

Dim iCtr As Long
Dim myArray As Variant
Dim newWks As Worksheet

Set newWks = Worksheets.Add
newWks.Cells.NumberFormat = "@"

For iCtr = 5 To Application.CustomListCount
myArray = Application.GetCustomListContents(iCtr)
newWks.Cells(1, iCtr - 4) _
.Resize(UBound(myArray) - LBound(myArray) + 1).Value _
= Application.Transpose(myArray)
Next iCtr
End Sub
Sub ImportCustomList()

Dim iCol As Long
Dim wks As Worksheet
Dim myArray As Variant

Set wks = ActiveSheet

With wks
For iCol = 1 To .Cells(1, .Columns.Count).End(xlToLeft).Column
myArray = .Range(.Cells(1, iCol), _
.Cells(.Rows.Count, iCol).End(xlUp)).Value
Application.AddCustomList listArray:=myArray
Next iCol
End With
End Sub

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm

Natasha wrote:

Could someone please tell me if there is a way of migrating Excel 2000 custom
lists to Excel 2003.

Thanks

--

Dave Peterson