Hi


Sub Example3()
Dim Lrow As Long
Dim CalcMode As Long
Dim StartRow As Long
Dim EndRow As Long
With Application
CalcMode = .Calculation
.Calculation = xlCalculationManual
.ScreenUpdating = False
End With

With ActiveSheet
.DisplayPageBreaks = False
StartRow = 1
EndRow = .Cells(.Rows.Count, "E").End(xlUp).Row
For Lrow = EndRow To StartRow Step -1
If IsError(.Cells(Lrow, "E").Value) Then
'Do nothing, This avoid a error if there is a error in the cell

ElseIf .Cells(Lrow, "E").Value = "" Then .Rows(Lrow).Delete
'This will delete each row if the cell is empty or have a formula that evaluates to ""

End If
Next
End With
With Application
.ScreenUpdating = True
.Calculation = CalcMode
End With
End Sub


See also
http://www.rondebruin.nl/delete.htm




--
Regards Ron de Bruin
http://www.rondebruin.nl


"Liam Tutty" wrote in message
...

Does anybody know of any way to do this...I have to compile a
spreadsheet every month for work, and always end up spending hourse
deleting rows where the information is not all present. Is there any
way I can say, Delete every row which has no information in Column E.

This would save me literally about 4 hours at the end of each month.

Thanks in advance,
Liam.


--
Liam Tutty
------------------------------------------------------------------------
Liam Tutty's Profile: http://www.excelforum.com/member.php...o&userid=29704
View this thread: http://www.excelforum.com/showthread...hreadid=494156