One way which could achieve this ..

Sample implementation at:
http://cjoint.com/?lxhD0otyVR
Auto-Summarizing WorkSheets_wks.xls

In Sheet1
Put in K6:
=IF(A6="","",ROW(A1))
Copy down to say, K15, to cover the max expected data range
(Leave K1:K5 empty)

In Sheet2
Put in K6:
=IF(A6="","",ROW(A1)+MAX(Sheet1!K:K))
Copy down to say, K15, to cover the max expected data range
(Leave K1:K5 empty)

In Sheet3
Put in K6:
=IF(A6="","",ROW(A1)+MAX(Sheet2!K:K))
Copy down to say, K15, to cover the max expected data range
(Leave K1:K5 empty)

In Sheet4
Put in K6:
=IF(A6="","",ROW(A1)+MAX(Sheet3!K:K))
Copy down to say, K15, to cover the max expected data range
(Leave K1:K5 empty)

In a new sheet: Summ
Same labels placed in A5:J5

Put in A6:

=IF(ISERROR(SMALL(Sheet1!$K:$K,ROW(A1))),
IF(ISERROR(SMALL(Sheet2!$K:$K,ROW(A1)-COUNT(Sheet1!$K:$K))),
IF(ISERROR(SMALL(Sheet3!$K:$K,ROW(A1)-
(COUNT(Sheet1!$K:$K)+COUNT(Sheet2!$K:$K)))),
IF(ISERROR(SMALL(Sheet4!$K:$K,ROW(A1)-
(COUNT(Sheet1!$K:$K)+COUNT(Sheet2!$K:$K)+COUNT(She et3!$K:$K)))),"",
INDEX(Sheet4!A:A,MATCH(SMALL(Sheet4!$K:$K,ROW(A1)-
(COUNT(Sheet1!$K:$K)+COUNT(Sheet2!$K:$K)+COUNT(She et3!$K:$K))),Sheet4!$K:$K,
0))),
INDEX(Sheet3!A:A,MATCH(SMALL(Sheet3!$K:$K,ROW(A1)-
(COUNT(Sheet1!$K:$K)+COUNT(Sheet2!$K:$K))),Sheet3! $K:$K,0))),
INDEX(Sheet2!A:A,MATCH(SMALL(Sheet2!$K:$K,ROW(A1)-
COUNT(Sheet1!$K:$K)),Sheet2!$K:$K,0))),
INDEX(Sheet1!A:A,MATCH(SMALL(Sheet1!$K:$K,ROW(A1)) ,Sheet1!$K:$K,0)))

Copy A6 across to J6, fill down to cover the total expected range in the 4
sheets. In this example, the total expected range is: 15 rows per sheet x 4
sheets = 60 rows.

The summary sheet will return exactly what's desired ..
--
Rgds
Max
xl 97
---
Singapore, GMT+8
xdemechanik
http://savefile.com/projects/236895
--
"Summary Worksheets" <Summary wrote in
message ...
Is there a way to populate a summary worksheet with the details of 4 other
worksheets, all of which have the same number of columns (A:J with the
labels
on row 5) yet have different numbers of rows (each sheet will have a
different number of rows with the data beginning on row 6 in each sheet).

Is it possible to do without running a macro so that the summary sheet
will
look to be automatically populated with as many rows as there are on sheet
number 1, then look to be populated with as many rows as there are on
sheet
number 2, etc.

Any help would be much appreciated.
Thanks
Tony