One non-array formulas play which will deliver what you want ..

Assume the table below is in Sheet1,
cols A to C, data from row2 down

Name Class Score
Peter 3A 17
Mary 3B 14
Sam 2A 13
etc

Use an empty col, say col E

Put in E2: =IF(C2="","",C2-ROW()/10^10)
Copy E2 down to say, E100, to cover the max expected data
(Leave E1 empty)

In Sheet2
----------
With the same headers in A1:C1, viz.: Name Class Score

Put in A2:

=IF(ISERROR(LARGE(Sheet1!$E:$E,ROWS($A$1:A1))),"", INDEX(Sheet1!A:A,MATCH(LAR
GE(Sheet1!$E:$E,ROWS($A$1:A1)),Sheet1!$E:$E,0)))

Copy A2 across to C2, fill down to C100
(cover the same range size as was done in col E in Sheet1)

Sheet2 will return the desired auto-sort results (descending scores)
from the table in Sheet1

In the event of any tied scores, the data lines will appear in the same
relative order that they are in Sheet1

Adapt to suit ..
--
Rgds
Max
xl 97
---
Singapore, GMT+8
xdemechanik
http://savefile.com/projects/236895
--
"Freshman" wrote in message
...
Dear all,

I've a table of three columns, namely : Name, Class & Score.

Peter 3A 17
Mary 3B 14
Sam 2A 13

So, in the next session, if Mary's total score is more than Peter's, then
Mary's row of record will jump from row 2 to row 1 and Peter's row will
descend one row down automatically (i.e.without pressing the sort button).
My question is what formula/function should I enter so that the row
sequence
can jump in accordance with the total score of each person. Please advise.

Thanks in advance.