On Dec 7, 10:25 am, "Bob Phillips" wrote:
=IF(ISERROR(SMALL(IF($B$12:$B$208=$M$1,ROW($A12:$A 208)-MIN(ROW($A12:$A208))+1,""),ROW($A1))),"",
INDEX($B$12:$B$208,SMALL(IF($B$12:$B$208=$M$1,ROW( $A12:$A208)-MIN(ROW($A12:$A208))+1,""),ROW($A1))))

and

=IF(ISERROR(SMALL(IF($B$12:$B$208=$M$1,ROW($A12:$A 208)-MIN(ROW($A12:$A208))+1,""),ROW($A1))),"",
INDEX($F$12:$F$208,SMALL(IF($B$12:$B$208=$M$1,ROW( $A12:$A208)-MIN(ROW($A12:$A208))+1,""),ROW($A1))))

which are both array formulae, and should be committed with
Ctrl-Shift-Enter, not just Enter.
Excel will automatically enclose the formula in braces (curly brackets), do
not try to do this manually.
When editing the formula, it must again be array-entered.

Then drag-copy them down as far as you think you might need.

BTW, I assumed the target nme is in M1.

--
---
HTH

Bob

(there's no email, no snail mail, but somewhere should be gmail in my addy)

"OldMac77" wrote in message

...

Hello,

I have a spreadsheet with many children and their club dues. (It is
not very orderly.)
Names are in range B12 to B208 and their payments are in range F12 to
F208.
How can I write a formula that would create a list of all payments
made by "Brian Gumbs" .in another part of the spreadsheet?

eg
Brian G $23
Brian G $25
Brian G $50

(Windows XP, Excel 2003)

Thank you all,

OldMac

Hello again,

Thanks Bob, your formula works. Thanks also to the others who
responded.

Best wishes,

OldMac