Les

What is 'not as expected'. The structure of the code is a little wierd in
that your with...end with block refers to Sheets("Invoices"), but it does
nothing on that sheet if you are running this with another sheet active
(Recon??) as the Cells(....) references with all refer to recon. Perhaps
you meant to prefix all those references with a period (.) so it refers to
the Invoices sheet???

Sub DeleteInvoice()
'
Dim i As Long, iLastRow As Long
Dim myInv As String
myInv = InputBox("PLease enter the number of the invoice to
delete...", "DELETE INVOICE", "024908")
With Sheets("Invoices")
iLastRow = .Cells(Rows.Count, "A").End(xlUp).Row
For i = iLastRow To 1 Step -1
If .Cells(i, "A").Value = myInv Then
.Rows(i).Delete
End If
Next i
End With
End Sub

--
HTH
Nick Hodge
Microsoft MVP - Excel
Southampton, England
DTHIS
web: www.nickhodge.co.uk
blog: www.nickhodge.co.uk/blog/

FREE UK OFFICE USER GROUP MEETING, MS READING, 27th APRIL 2007
www.officeusergroup.co.uk

"Les Stout" wrote in message
...
Hi all, i am using the code below and it is not working as i want it to,
could somebody please help me ??
When i want to run this i am in the sheet Recon and it counts the rows
in recon ??

Sub DeleteInvoice()
'
Dim i As Long, iLastRow As Long
Dim myInv As String
myInv = InputBox("PLease enter the number of the invoice to
delete...", "DELETE INVOICE", "024908")
With Sheets("Invoices")
iLastRow = Cells(Rows.Count, "A").End(xlUp).Row
For i = iLastRow To 1 Step -1
If Cells(i, "A").Value = myInv Then
Rows(i).Delete
End If
Next i
End With
End Sub


Les Stout

*** Sent via Developersdex http://www.developersdex.com ***