If you don't mind a pair of helper columns try this -

Sample XY data:
A2=0 B2=0
A3=1 B3=B2+0.1

Select A2:B3 and drag the little handle down to say 10002

F1=100 ' every n'th plot

helper columns:
C2 =OFFSET($A$2,(ROW(C2)-ROW($A$2))*$F$1,0)
D2 =OFFSET($B$2,(ROW(D2)-ROW($B$2))*$F$1,0)

Copy C2:D2 down to say 1002+, enough for every 10th point (later you'll need
more for your 59k)

With F1=100 then D103 & below will = 0, doesn't matter how many of these but
maintain at least as many as will ever be needed.

Define these names, Ctr-F3
Name: CatX
=OFFSET($C$2,0,0,COUNTA($B$2:$B$65535)/$F$1+1,1)

Name: Ser1
=OFFSET($D$2,0,0,COUNTA($B$2:$B$65535)/$F$1+1,1)

Make a chart:
Select a couple of cells containing numbers surrounded by blanks
With the chart wizard choose say Line without markers and go straight to
Finish

Select the dummy two point series
In the Edit bar replace the formula

=SERIES(,MyBook.xls!CatX,MyBook.xls!Ser1,1)

You may need to bracket 'MyBook.xls' with apostrophes if any non-standard
characters exist in the xls name (eg space).

Hopefully your Series is now as anticipated.

Change the value in F1 to suit. How much you can increase it (every n'th)
might depend on how spiky your chart is.

Regards,
Peter T


"inquirer" wrote in message
u...
Further to an earlier post, I have about 59000 data points that I want
to plot on an line chart. The points for the x axis are sorted in
ascending order.
I can plot the first 32000 points ok as Series 1 but how can I then plot
points from 32001 on so they plot on the end of series 1? I have treid
defining series 2 as 32001 onwards but these points do not plot on the
end of series 1, rather they start again at the origin.
Any help much appreciated
Thanks
Chris