Try this against a copy of your worksheet--it destroys the original data when it
builds the output:
Option Explicit
Sub testme()
Dim iRow As Long
Dim LastRow As Long
Dim FirstRow As Long
Dim wks As Worksheet
Set wks = Worksheets("Sheet1")
With wks
FirstRow = 1
LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
For iRow = LastRow To FirstRow + 1 Step -1
If .Cells(iRow, "A").Value = .Cells(iRow - 1, "A").Value Then
.Cells(iRow - 1, "B").Value _
= .Cells(iRow - 1, "B").Value _
& "," & .Cells(iRow, "B").Value
.Rows(iRow).Delete
End If
Next iRow
End With
End Sub
And make sure your data is sorted by column A.
If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm
sp123 wrote:
Hi All
Need some urgent help
i have worksheet with the following format
1111 abc
1111 xyz
1234 qwe
I need help to merge column b values depending on column A.If two rows
have the same value in column a then i would like to merge column b as
shown below.
So i need the above data to appear as
1111 abc,xyz
1234 qwe
thanks
sp123
--
sp123
------------------------------------------------------------------------
sp123's Profile: http://www.excelforum.com/member.php...o&userid=31163
View this thread: http://www.excelforum.com/showthread...hreadid=521943
--
Dave Peterson