What do you mean by Save the form?


You can use Userform1.printform

if that doesn't give you what you want, then you can get a copy of the
userform as a graphic and place it on a worksheet. Then manipulate it as
you need; then print it out.

Here is code that will print a userform as a graphic on a worksheet:


Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, _
ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

'Public Const VK_SNAPSHOT = &H2C

Public Const VK_SNAPSHOT = 44
Public Const VK_LMENU = 164
Public Const KEYEVENTF_KEYUP = 2
Public Const KEYEVENTF_EXTENDEDKEY = 1


Sub Test()
UserForm1.Show
End Sub


In the userform module:




Private Sub CommandButton1_Click()
' keybd_event VK_SNAPSHOT, 0, 0, 0
DoEvents
keybd_event VK_LMENU, 0, _
KEYEVENTF_EXTENDEDKEY, 0 ' key down
keybd_event VK_SNAPSHOT, 0, _
KEYEVENTF_EXTENDEDKEY, 0
keybd_event VK_SNAPSHOT, 0, _
KEYEVENTF_EXTENDEDKEY + _
KEYEVENTF_KEYUP, 0
keybd_event VK_LMENU, 0, _
KEYEVENTF_EXTENDEDKEY + _
KEYEVENTF_KEYUP, 0
DoEvents
Workbooks.Add
Application.Wait Now + TimeValue("00:00:01")
ActiveSheet.PasteSpecial Format:="Bitmap", _
Link:=False, DisplayAsIcon:=False
ActiveSheet.Range("A1").Select
ActiveWindow.SelectedSheets.PrintOut Copies:=1
ActiveWorkbook.Close False
End Sub

--
Regards,
Tom Ogilvy


"dstyles782001"
wrote in message
news:dstyles782001.23j5wz_1140443101.6881@excelfor um-nospam.com...

i am working on a userform using vb editor. i would like to have the
users print and save the form. i need a code to accomplish both.
thanks


--
dstyles782001
------------------------------------------------------------------------
dstyles782001's Profile:
http://www.excelforum.com/member.php...o&userid=31727
View this thread: http://www.excelforum.com/showthread...hreadid=514390