Hi,

It has already been pointed out that if you set the columnwidths
property to be wider that the control the horizontal scroller will
appear. To determine how wide it should be you can use the following
function.
It creates a label control on the fly and uses that to determine the
widest piece of text.

Once the list box is populated you can use this command.
ListBox1.ColumnWidths = GetWidth(ListBox1)


'-------------------------------------------
Function GetWidth(MyList As msforms.ListBox, _
Optional ColIndex As Integer)
Dim objLabel As New Control
Dim intItem As Integer
Dim lngMaxWidth As Long

' create label to determine width of listbox contents
Set objLabel = Me.Controls.Add("Forms.Label.1", "xxxTemp", False)
With objLabel
.WordWrap = False
With .Font ' match font attributes
.Name = MyList.Font.Name
.Size = MyList.Font.Size
.Bold = MyList.Font.Bold
.Italic = MyList.Font.Italic
End With
For intItem = 0 To MyList.ListCount - 1
.AutoSize = False
.Width = 1000
.Caption = MyList.List(intItem, ColIndex)
.AutoSize = True
If .Width lngMaxWidth Then lngMaxWidth = .Width
Next
Me.Controls.Remove .Name
End With
Set objLabel = Nothing
GetWidth = lngMaxWidth + 10
End Function
'-------------------------------------------

Cheers
Andy

Justin Starnes wrote:

Unfortunately, the problem with that solution is that I cannot accurately
determine the width of the longest string. To solve that problem, I tried
using the GetTextExtent32 function to obtain the length of the string.
Hoewver, when I set columnwidths to that value, I don't get the correct
result. ColumnWidths defaults to points for the specification. Is
GetTextExtent returning twips, pixels, etc.? I tried to convert it to
points, but am not having much luck. Any ideas?



"Robin Hammond" wrote in message
...

Just set the columnwidth to more than the width of the listbox in the
properties pane in the VBE.

Robin Hammond
www.enhanceddatasystems.com

"Justin Starnes" wrote in message
...

I have a listbox on a userform that contains entries longer than the
length of the listbox. Thus, I'm looking to add a horizontal scrollbar to
the listbox but am having trouble finding a code sample for userforms.
Does anyone have an example or can help me get one working with userforms?

Thanks,
Justin






--

Andy Pope, Microsoft MVP - Excel
http://www.andypope.info