If I were doing it manually, I'd just do Edit|Replace 11 times.

As a macro:

Option Explicit
Sub testme()

Dim myRng As Range
Dim iCtr As Long
Dim myFroms As Variant
Dim myTos As Variant

Set myRng = Nothing
On Error Resume Next
Set myRng = Application.InputBox("Select a cell in your column:", _
Default:=ActiveCell.Address(0, 0), _
Type:=8).Cells(1).EntireColumn
On Error GoTo 0

If myRng Is Nothing Then
Exit Sub
End If

myFroms = Array(1, 3, 5, 7, 8, 9, "a", "c", "f", "j", "Z")
myTos = Array("Personal property", _
"personal property and vehicle", _
"vehicle and personal property", _
"cosigner", _
"intangible personal property", _
"draft check", _
"merchandise/household goods", _
"clothing (sales finance)", _
"fixtures (sales finance)", _
"musical equipment (sales finance)", _
"residence (mobile home sales finance)")

If UBound(myFroms) < UBound(myTos) Then
MsgBox "Design error!"
Exit Sub
End If

For iCtr = LBound(myFroms) To UBound(myFroms)
myRng.Replace What:=myFroms(iCtr), _
Replacement:=myTos(iCtr), LookAt:=xlWhole, _
SearchOrder:=xlByRows, MatchCase:=False
Next iCtr

End Sub


Jason Trolian wrote:

I am uploading many different files into my database.
These files come in a spreadsheet. There is one
particular column that requires the conversion of a
single didget product code to a discription.

I want to know how to write a macro that I would be able
to select that column, run it and it would convert the
data for me. The data would need to convert as follows:

1 = Personal property
3 = personal property and vehicle
5 = vehicle and personal property
7 = cosigner
8 = intangible personal property
9 = draft check
A = merchandise/household goods
C = clothing (sales finance)
F = fixtures (sales finance)
J = musical equipment (sales finance)
Z = residence (mobile home sales finance)

Thank you in advance,
JT

--

Dave Peterson