Jo,

The actual code will depend on what specifically you want to do
with the list. Try the following code to create a tree-like list
in an Excel worksheet.

Sub Start()

Const START_FOLDER_NAME = "H:\ExcelProjects" '<<< CHANGE
Dim FSO As Object
Dim Rng As Range
Set FSO = CreateObject("Scripting.FileSystemObject")
Set Rng = Range("A1")
Rng.Value = START_FOLDER_NAME
Set Rng = Rng(2, 2)
ProcessOneFolder FSO.GetFolder(START_FOLDER_NAME), Rng

End Sub


Sub ProcessOneFolder(Fldr As Object, Rng As Range)

Dim OneFile As Object
Dim OneFolder As Object
For Each OneFile In Fldr.Files
Rng.Value = OneFile.Path
Set Rng = Rng(2, 1)
Next OneFile
For Each OneFolder In Fldr.SubFolders
Rng.Value = OneFolder.Path
Set Rng = Rng(2, 2)
ProcessOneFolder OneFolder, Rng
Set Rng = Rng(1, 0)
Next OneFolder

End Sub



--
Cordially,
Chip Pearson
Microsoft MVP - Excel
Pearson Software Consulting, LLC
www.cpearson.com



"Jo" wrote in message
...
Has anyone got any code to return a list of the contents of a
directory and its sub folders?

TIA