How can I add non-adjacent cells with a formula
 

I have 24 columns. In columns 25 and 26, I want the sum totals of every other
column to its left. In other words, column 25 would show the sum of columns,
1,3,5,7,... and column 26 the sum of columns 2,4,6,8,....

I have manually entered the formula =sum(a1+c1+e1+.....x1). Is there an
easier way?

Thanks in advance

Hi

to sum the EVEN columns
=SUM(IF(MOD(COLUMN(A1:X1),2)=0,A1:X1,0))

to sum the ODD columns
=SUM(IF(MOD(COLUMN(A1:X1),2)=1,A1:X1,0))

NOTE: these are array formulas so they need to be entered with control &
shift & enter, not just enter.

Cheers
JulieD

"dhodges00" wrote in message
...
I have 24 columns. In columns 25 and 26, I want the sum totals of every
other
column to its left. In other words, column 25 would show the sum of
columns,
1,3,5,7,... and column 26 the sum of columns 2,4,6,8,....

I have manually entered the formula =sum(a1+c1+e1+.....x1). Is there an
easier way?

Thanks in advance

1]

=SUMPRODUCT(--(MOD(COLUMN($A$1:$X$1)-CELL("Col",$A$1)+0,2)=0),$A$1:$X$1)

2]

=SUMPRODUCT(--(MOD(COLUMN($A$1:$X$1)-CELL("Col",$A$1)+1,2)=0),$A$1:$X$1)

dhodges00 wrote:
I have 24 columns. In columns 25 and 26, I want the sum totals of every other
column to its left. In other words, column 25 would show the sum of columns,
1,3,5,7,... and column 26 the sum of columns 2,4,6,8,....

I have manually entered the formula =sum(a1+c1+e1+.....x1). Is there an
easier way?

Thanks in advance

For a non-array option, you could try:

Odd columns:
=SUMPRODUCT((MOD(COLUMN(A1:X1)+1,2)=0)*(A1:X1))

Even columns:
=SUMPRODUCT((MOD(COLUMN(A1:X1),2)=0)*(A1:X1))
--

HTH,

RD
==============================================
Please keep all correspondence within the Group, so all may benefit!
==============================================


"JulieD" wrote in message
...
Hi

to sum the EVEN columns
=SUM(IF(MOD(COLUMN(A1:X1),2)=0,A1:X1,0))

to sum the ODD columns
=SUM(IF(MOD(COLUMN(A1:X1),2)=1,A1:X1,0))

NOTE: these are array formulas so they need to be entered with control &
shift & enter, not just enter.

Cheers
JulieD

"dhodges00" wrote in message
...
I have 24 columns. In columns 25 and 26, I want the sum totals of every
other
column to its left. In other words, column 25 would show the sum of
columns,
1,3,5,7,... and column 26 the sum of columns 2,4,6,8,....

I have manually entered the formula =sum(a1+c1+e1+.....x1). Is there an
easier way?

Thanks in advance