ExcelBanter

ExcelBanter (https://www.excelbanter.com/)
-   Excel Worksheet Functions (https://www.excelbanter.com/excel-worksheet-functions/)
-   -   nested sumif or sumif with two criteria (https://www.excelbanter.com/excel-worksheet-functions/20527-nested-sumif-sumif-two-criteria.html)

dshigley April 4th 05 09:49 PM

nested sumif or sumif with two criteria
 
Say for example I have three columns; the first is a name column, second is
color and third is cost. I am trying to create a formula that will sum all
cells in the third column (cost) that matches the criteria of the name "Bob"
in column A AND "Red" in column B. I know I am close and I know I can use
the "*" somehow but I can't figure out the syntax. Any help is appreciated.

Duke Carey April 4th 05 10:01 PM

Try


=sumproduct(--(A2:A100="Bob"),--(B2:B100="Red"),C2:C100)


"dshigley" wrote:

Say for example I have three columns; the first is a name column, second is
color and third is cost. I am trying to create a formula that will sum all
cells in the third column (cost) that matches the criteria of the name "Bob"
in column A AND "Red" in column B. I know I am close and I know I can use
the "*" somehow but I can't figure out the syntax. Any help is appreciated.


dshigley April 4th 05 10:11 PM

I did a search on my question before I posted and one of last years answers
was the exact same thing. I tried that formula but cannot seem to get it to
work. Thanks though.

Dan

"Duke Carey" wrote:

Try


=sumproduct(--(A2:A100="Bob"),--(B2:B100="Red"),C2:C100)


"dshigley" wrote:

Say for example I have three columns; the first is a name column, second is
color and third is cost. I am trying to create a formula that will sum all
cells in the third column (cost) that matches the criteria of the name "Bob"
in column A AND "Red" in column B. I know I am close and I know I can use
the "*" somehow but I can't figure out the syntax. Any help is appreciated.


Peter Aitken April 4th 05 10:33 PM

"dshigley" wrote in message
...
Say for example I have three columns; the first is a name column, second
is
color and third is cost. I am trying to create a formula that will sum
all
cells in the third column (cost) that matches the criteria of the name
"Bob"
in column A AND "Red" in column B. I know I am close and I know I can use
the "*" somehow but I can't figure out the syntax. Any help is
appreciated.


In my experience, if you want to sum based on 2 or more criteria you have to
use DSUM. SUMIF works with only 1 criterion.


--
Peter Aitken

Remove the crap from my email address before using.



bj April 4th 05 11:19 PM

Duke's equationm should have worked
put in a temporary column and use
=if(a2="Bob",1,2)
and copy down to row 100
See3 if all the "Bob" come up
to check if you might have extra spaces or something.
do likewise with "Red"

"dshigley" wrote:

I did a search on my question before I posted and one of last years answers
was the exact same thing. I tried that formula but cannot seem to get it to
work. Thanks though.

Dan

"Duke Carey" wrote:

Try


=sumproduct(--(A2:A100="Bob"),--(B2:B100="Red"),C2:C100)


"dshigley" wrote:

Say for example I have three columns; the first is a name column, second is
color and third is cost. I am trying to create a formula that will sum all
cells in the third column (cost) that matches the criteria of the name "Bob"
in column A AND "Red" in column B. I know I am close and I know I can use
the "*" somehow but I can't figure out the syntax. Any help is appreciated.


Harlan Grove April 5th 05 03:34 AM

"dshigley" wrote...
I did a search on my question before I posted and one of last years answers
was the exact same thing. I tried that formula but cannot seem to get it

to
work. Thanks though.

....

In what way does the formula not work? It does work if you've given correct
specs and have ensured your data range contains no leading or trailing
spaces in the entries in columns A and B and all entries are numbers rather
than text looking like numbers in column C.

"Duke Carey" wrote:
Try

=sumproduct(--(A2:A100="Bob"),--(B2:B100="Red"),C2:C100)

....

Basic formula debugging. What do the formulas

=COUNTIF(A2:A100,"Bob")
=SUMPRODUCT(--(TRIM(A2:A100)="Bob"))
=SUMPRODUCT(--(TRIM(SUBSTITUTE(A2:A100,CHAR(168),""))="Bob"))

=COUNTIF(B2:B100,"Red")
=SUMPRODUCT(--(TRIM(B2:B100)="Red"))
=SUMPRODUCT(--(TRIM(SUBSTITUTE(B2:B100,CHAR(168),""))="Red"))

=SUM(C2:C100)
=SUMPRODUCT(--C2:C100)

return? If the first 3 and/or second 3 return different results, you have
either normal ASCII or nonbreaking HTML spaces in your columns A and/or B.
If the last two formulas return different results, some or all of your
column C values are text. The most robust formula would be

=SUMPRODUCT(--(TRIM(SUBSTITUTE(A2:A100,CHAR(168),""))="Bob"),
--(TRIM(SUBSTITUTE(B2:B100,CHAR(168),""))="Red"),--C2:C100)

However, the best approach would be to clean up the data in A2:C100.




All times are GMT +1. The time now is 09:06 PM.

Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
ExcelBanter.com