OFFSET HELP
 

I am using an OFFSET function to match names in column B to comments in
column R. The problem is that when the formula finds the first match it
stops. I need it to continue. Below is a copy of the formula I am using:

=OFFSET('Data '!B1,MATCH('Master TL Sheet '!C6,'Data '!B2:B800,0),16)

This workbook contains two sheets "master" is the report and the second is
the data. This is survey data for 96 managers with multiple responses for
each. Is the a macro that might be easier?

OFFSET HELP
 

Try entering this in cell D2 and copy it down until you get #NUM error. Make
sure the worksheet references are correct - your post shows a trailing space
in the sheet name so I also included one.

Commit the formula w/ Cntrl+Shift+Enter or you will get #VALUE

=INDEX('Data '!$R$2:$R$800,SMALL(IF('Data '!$B$2:$B$800='Master TL Sheet
'!$C$6,ROW(INDIRECT("1:"&ROWS('Data '!$B$2:$B$800))),""),ROWS(D$2:D2)))

If you don't like the #NUM and prefer a blank try

=IF(COUNTIF('Data '!$B$2:$B$800,'Master TL Sheet
'!$C$6)<ROWS(D$2:D2),"",INDEX('Data '!$R$2:$R$800,SMALL(IF('Data
'!$B$2:$B$800='Master TL Sheet '!$C$6,ROW(INDIRECT("1:"&ROWS('Data
'!$B$2:$B$800))),""),ROWS(D$2:D2))))

also commited w/Cntrl+Shift+Enter

"Scott@CW" wrote:

I am using an OFFSET function to match names in column B to comments in
column R. The problem is that when the formula finds the first match it
stops. I need it to continue. Below is a copy of the formula I am using:

=OFFSET('Data '!B1,MATCH('Master TL Sheet '!C6,'Data '!B2:B800,0),16)

This workbook contains two sheets "master" is the report and the second is
the data. This is survey data for 96 managers with multiple responses for
each. Is the a macro that might be easier?