Sorry, there was a missing parenthesis, the formula should have been
=SUM((data-AVERAGE(data))^4)/VARP(data)^2/n
A slightly simpler array formula is
=AVERAGE((data-AVERAGE(data))^4)/VARP(data)^2
Or you can avoid array entry with
=SUMPRODUCT((data-AVERAGE(data))^4)/VARP(data)^2/n

I also miscopied the final divisor for the second formula, which should be
=(KURT(data)*(n-2)*(n-3)+3*(n-1)^2)/(n-1)/(n+1)

All four formulas should give the same answer. If you use the example data
from Help for KURT
3, 4, 5, 2, 3, 4, 5, 6, 4, 7
then all four formulas return 2.36867899309423

Jerry

"MikhailGr" wrote:

I have some questions:
1.I understand how SUM(A1:A100) works. But I do not understand how
SUM(A1:A100-C5)works. Excel doesnt allow me to enter this expression.
At what point should I press Ctrl+Shift+Enter?

2.Are you saying that if I modify Excels Kurtosis formula as you suggested,
I will get the formula I want?

Thanks.


"Jerry W. Lewis" wrote:

Two ways are

=SUM(data-AVERAGE(data))^4)/VARP(data)^2/n
array entered (Ctrl-Shift-Enter), or wrapped in a VBA Evaluate() function.

=(KURT(data)*(n-2)*(n-3)+3*(n-1)^2)/(n-1)/(n-2)

Jerry

"Anastasia Gryaznov" wrote:

Hello,
Could you please help me to encode (make it in one function) the following
formula:

[SUM[(X(i) - Mean(X))^4] / ( ((SUM[(X(i) - Mean(X))^2] / N)^2) ] / N

where X(i) is group of numbers stored in cell range A1:A100.

Thanks.