ExcelBanter - SUMIF HELP

try
=SUMPRODUCT(--(NOT(ISERROR(FIND("20070.53661.FMS",'07-08 Object Code
Breakdown'!$E$4:$E$1000,1)))),'07-08 Object Code Breakdown'!$B$4:$B$1000)

if the string you're looking for can be anywhere within the longer string.

or a little shorter:
=SUMPRODUCT(--(RIGHT('07-08 Object Code
Breakdown'!$E$4:$E$1000,15)="20070.53661.FMS"),'07-08 Object Code
Breakdown'!$B$4:$B$1000)

if the string you're looking for is always the last 15 characters

or
=SUMPRODUCT(--(MID('07-08 Object Code
Breakdown'!$E$4:$E$1000,31,15)="20070.53661.FMS"), '07-08 Object Code
Breakdown'!$B$4:$B$1000)

if the the string you're looking for always starts at character 31, and it
doesn't matter if there are more characters after 'FMS' (which is closest to
whatyou asked).
--
p45cal

"MO" wrote:

I've used the below formula and it works. However, I need to us it again but
I won't have ALL of the information that is in quotes. The only thing that
will be for certain is the 20070.53661.FMS. However, what precedes the
information will be various numbers but the periods(.) will always be the
same place.

Can someone help me with a SUMIF formula for this?

=SUMIF('07-08 Object Code
Breakdown'!E4:E1000,"53000.5300200010.00300.206004 .20070.53661.FMS",'07-08
Object Code Breakdown'!B4:B1000)
--
Thank you for your help
MO
Albany, NY