... If I did, however, want a report / sheet
with only a specific date,
what would I have to put and where?

One play which would deliver this ..

Assume the source data is now in Sheet1, cols A to D*, data from row2 down,
with the key col = col D ("DeadLine")
*Name, What, StartDate, DeadLine

Assuming 2 empty cols to the right, cols E & F

Put in F1: =IF(Sheet2!A1="","",Sheet2!A1)

Put in E2: =IF(D2="","",IF(D2=$F$1,ROW(),""))

Copy E2 down to say, E100
to cover the max expected data range in cols A to D

(Leave E1 empty)

In Sheet2
----------
A1 will be reserved for input of the deadline of interest
Input a date into A1, say: 01-Jul-2005

Paste the same col headers into A2:D2, viz.:
Name, What, StartDate, DeadLine

Put in A3:

=IF(ISERROR(SMALL(Sheet1!$E:$E,ROWS($A$1:A1))),"", INDEX(Sheet1!A:A,MATCH(SMA
LL(Sheet1!$E:$E,ROWS($A$1:A1)),Sheet1!$E:$E,0)))

Copy A3 across to D3, fill down to D101
(cover the same range as in col E in Sheet1)

Format cols C and D as dates

Sheet 2 will auto-extract only the rows from Sheet1 where the deadlines are
equal to the date input in A1. These will be bunched neatly at the top, with
blank rows below.

Adapt to suit ..

--
Rgds
Max
xl 97
---
GMT+8, 1° 22' N 103° 45' E
xdemechanik <atyahoo<dotcom
----